src/type3_AndroidCloud/anbox-master/cmake/LinuxCrossCompile.cmake

   1 set(CMAKE_SYSTEM_NAME Linux)
   2 set(CMAKE_SYSTEM_VERSION 1)
   3
   4 set(AC_NDK_PATH $ENV{AC_NDK_PATH} CACHE STRING "path of mir android bundle")
   5
   6 if (NOT DEFINED AC_TARGET_MACHINE)
   7   set(AC_TARGET_MACHINE $ENV{AC_TARGET_MACHINE} CACHE STRING "target machine")
   8 endif()
   9 if (NOT DEFINED AC_GCC_VARIANT)
  10   set(AC_GCC_VARIANT $ENV{AC_GCC_VARIANT} CACHE STRING "gcc variant required")
  11 endif()
  12
  13 set(HOST_CMAKE_C_COMPILER /usr/bin/cc)
  14 set(HOST_CMAKE_CXX_COMPILER /usr/bin/c++)
  15
  16 set(CMAKE_C_COMPILER   /usr/bin/${AC_TARGET_MACHINE}-gcc${AC_GCC_VARIANT})
  17 set(CMAKE_CXX_COMPILER /usr/bin/${AC_TARGET_MACHINE}-g++${AC_GCC_VARIANT})
  18
  19 # where to look to find dependencies in the target environment
  20 set(CMAKE_FIND_ROOT_PATH  "${AC_NDK_PATH}")
  21
  22 #treat the chroot's includes as system includes
  23 include_directories(SYSTEM "${AC_NDK_PATH}/usr/include" "${AC_NDK_PATH}/usr/include/${AC_TARGET_MACHINE}")
  24 list(APPEND CMAKE_SYSTEM_INCLUDE_PATH "${AC_NDK_PATH}/usr/include" "${AC_NDK_PATH}/usr/include/${AC_TARGET_MACHINE}" )
  25
  26 # Add the chroot libraries as system libraries
  27 list(APPEND CMAKE_SYSTEM_LIBRARY_PATH
  28   "${AC_NDK_PATH}/lib"
  29   "${AC_NDK_PATH}/lib/${AC_TARGET_MACHINE}"
  30   "${AC_NDK_PATH}/usr/lib"
  31   "${AC_NDK_PATH}/usr/lib/${AC_TARGET_MACHINE}"
  32 )
  33
  34 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH FALSE)
  35 set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
  36 set(CMAKE_EXECUTABLE_RUNTIME_C_FLAG "-Wl,-rpath-link,")
  37 set(CMAKE_EXECUTABLE_RUNTIME_CXX_FLAG "-Wl,-rpath-link,")
  38 set(CMAKE_INSTALL_RPATH "${AC_NDK_PATH}/lib:${AC_NDK_PATH}/lib/${AC_TARGET_MACHINE}:${AC_NDK_PATH}/usr/lib:${AC_NDK_PATH}/usr/lib/${AC_TARGET_MACHINE}")
  39
  40 set(ENV{PKG_CONFIG_PATH} "${AC_NDK_PATH}/usr/lib/pkgconfig:${AC_NDK_PATH}/usr/lib/${AC_TARGET_MACHINE}/pkgconfig")
  41 set(ENV{PKG_CONFIG_SYSROOT_DIR} "${AC_NDK_PATH}")
  42
  43 #use only the cross compile system
  44 set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER)
  45 set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  46 set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)