src/type3_AndroidCloud/anbox-master/CMakeLists.txt

   1 project(anbox C CXX)
   2 cmake_minimum_required(VERSION 2.8.2)
   3
   4 include(CTest)
   5 include(GNUInstallDirs)
   6
   7 if (NOT CMAKE_BUILD_TYPE)
   8     message(STATUS "No build type selected, default to RelWithDebInfo")
   9     set(CMAKE_BUILD_TYPE "RelWithDebInfo")
  10 endif()
  11
  12 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  13
  14 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -pedantic -Wno-variadic-macros -Wextra -fPIC")
  15
  16 # By default, all symbols are visible in the library. We strip out things we don't
  17 # want at link time, by running a version script (see unity-scopes.map and the
  18 # setting of LINK_FLAGS below).
  19 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=default")
  20
  21 set(C_AND_CXX_WARNINGS "-pedantic -Wall -Wextra")
  22
  23 # Some additional warnings not included by the general flags set above.
  24 set(EXTRA_C_WARNINGS "-Wcast-align -Wcast-qual -Wformat -Wredundant-decls -Wswitch-default")
  25 set(EXTRA_CXX_WARNINGS "-Wnon-virtual-dtor -Wold-style-cast")
  26
  27 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${C_AND_CXX_WARNINGS}")
  28 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${EXTRA_C_WARNINGS}")
  29
  30 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++14 ${C_AND_CXX_WARNINGS}")
  31 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${EXTRA_C_WARNINGS}")
  32 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${EXTRA_CXX_WARNINGS}")
  33
  34 # -fno-permissive causes warnings with clang, so we only enable it for gcc
  35 if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU")
  36   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-permissive")
  37 endif()
  38
  39 string(TOLOWER "${CMAKE_BUILD_TYPE}" cmake_build_type_lower)
  40
  41 if ("${cmake_build_type_lower}" STREQUAL "release" OR "${cmake_build_type_lower}" STREQUAL "relwithdebinfo")
  42   option(Werror "Treat warnings as errors" ON)
  43 else()
  44   option(Werror "Treat warnings as errors" OFF)
  45 endif()
  46
  47 if (${Werror})
  48     message(STATUS "Treat warnings as errors")
  49   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Werror")
  50   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Werror")
  51   if ("${cmake_build_type_lower}" STREQUAL "release" OR "${cmake_build_type_lower}" STREQUAL "relwithdebinfo")
  52     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-error=deprecated-declarations")
  53     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-error=deprecated-declarations")
  54   endif()
  55 endif()
  56
  57 set(CMAKE_INCLUDE_CURRENT_DIR ON)
  58
  59 find_package(Boost COMPONENTS filesystem log serialization system thread program_options)
  60 find_package(PkgConfig)
  61 find_package(Threads)
  62 find_package(EGL REQUIRED)
  63 find_package(GLESv2 REQUIRED)
  64 find_package(Protobuf REQUIRED)
  65
  66 pkg_check_modules(SDL2 sdl2 REQUIRED)
  67 pkg_check_modules(SDL2_IMAGE SDL2_image REQUIRED)
  68 pkg_check_modules(DBUS dbus-1 REQUIRED)
  69 pkg_check_modules(LXC lxc REQUIRED)
  70 pkg_check_modules(PROPERTIES_CPP properties-cpp REQUIRED)
  71 pkg_check_modules(LIBSYSTEMD libsystemd REQUIRED)
  72 pkg_check_modules(LIBCAP libcap REQUIRED)
  73
  74 message(STATUS "LXC version: ${LXC_VERSION}")
  75 if (${LXC_VERSION} VERSION_LESS 3.0)
  76   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DENABLE_LXC2_SUPPORT")
  77   message(STATUS "Building with LXC 2.x compatibility support")
  78 endif()
  79
  80 option(ENABLE_X11 "Enable X11 support" ON)
  81 if (ENABLE_X11)
  82   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DX11_SUPPORT")
  83 endif()
  84
  85 option(ENABLE_WAYLAND "Enable wayland support" ON)
  86 if (ENABLE_WAYLAND)
  87   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DWAYLAND_SUPPORT")
  88 endif()
  89
  90 option(ENABLE_MIR "Enable mir support" OFF)
  91 if (ENABLE_MIR)
  92   pkg_check_modules(MIRCLIENT mirclient REQUIRED)
  93   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DMIR_SUPPORT")
  94 endif()
  95
  96 if (NOT BINDERFS_PATH)
  97   set(BINDERFS_PATH "/dev/binderfs")
  98 endif()
  99
 100 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DEGL_NO_X11")
 101
 102 if((Protobuf_VERSION VERSION_GREATER "3.7") OR (Protobuf_VERSION VERSION_EQUAL "3.7"))
 103     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DUSE_PROTOBUF_CALLBACK_HEADER")
 104 endif()
 105
 106 #####################################################################
 107 # Enable code coverage calculation with gcov/gcovr/lcov
 108 # Usage:
 109 #  * Switch build type to coverage (use ccmake or cmake-gui)
 110 #  * Invoke make, make test, make coverage
 111 #  * Find html report in subdir coveragereport
 112 #  * Find xml report feasible for jenkins in coverage.xml
 113 #####################################################################
 114 IF(CMAKE_BUILD_TYPE MATCHES [cC][oO][vV][eE][rR][aA][gG][eE])
 115   SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -ftest-coverage -fprofile-arcs" )
 116   SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -ftest-coverage -fprofile-arcs" )
 117   SET(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -ftest-coverage -fprofile-arcs" )
 118   SET(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -ftest-coverage -fprofile-arcs" )
 119 ENDIF(CMAKE_BUILD_TYPE MATCHES [cC][oO][vV][eE][rR][aA][gG][eE])
 120
 121 find_package(GMock)
 122
 123 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++14 -fPIC")
 124
 125
 126 if (NOT ANBOX_VERSION)
 127     exec_program("git" ${CMAKE_SOURCE_DIR} ARGS "rev-parse --short HEAD" OUTPUT_VARIABLE GIT_COMMIT_HASH)
 128     set(ANBOX_VERSION "local-${GIT_COMMIT_HASH}")
 129 endif()
 130 if (ANBOX_VERSION_SUFFIX)
 131     set(ANBOX_VERSION "${ANBOX_VERSION}-${ANBOX_VERSION_SUFFIX}")
 132 endif()
 133 set(ANBOX_RESOURCE_DIR "${CMAKE_INSTALL_DATADIR}/anbox")
 134 set(ANBOX_RESOURCE_DIR_FULL "${CMAKE_INSTALL_FULL_DATADIR}/anbox")
 135 set(ANBOX_STATEDIR_FULL "${CMAKE_INSTALL_FULL_LOCALSTATEDIR}/lib/anbox")
 136 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/src/anbox/build/config.h.in
 137                ${CMAKE_CURRENT_SOURCE_DIR}/src/anbox/build/config.h)
 138
 139 add_subdirectory(external)
 140 add_subdirectory(src)
 141 add_subdirectory(tests)
 142 add_subdirectory(android)
 143
 144 if (NOT "${HOST_CMAKE_C_COMPILER}" STREQUAL "")
 145   message(STATUS "Host C compiler: ${HOST_CMAKE_C_COMPILER}")
 146   message(STATUS "Host C compiler: ${HOST_CMAKE_CXX_COMPILER}")
 147 endif()
 148
 149 option(SNAP_CONFINEMENT "Enable snap confinement support" OFF)
 150 if (SNAP_CONFINEMENT)
 151   message(STATUS "Building with support for snap confinement")
 152   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DENABLE_SNAP_CONFINEMENT")
 153 endif()
 154
 155 install(FILES data/ui/loading-screen.png DESTINATION ${ANBOX_RESOURCE_DIR}/ui)
 156
 157 # uninstall target
 158 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake_uninstall.cmake.in"
 159                "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 160                IMMEDIATE @ONLY)
 161 add_custom_target(uninstall "${CMAKE_COMMAND}"
 162                   -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")